Aminet 24/Aminet 24 (1998)(GTI - Schatztruhe)[!][Apr 1998].iso/Aminet/biz/demo/MaVi1_0T1A.lha/InstallDemo

Text File | 1998-02-10 | 4KB | 194 lines

; script to install MaVi, based on the PPage example

    ; set up a error cleanup routine

(onerror
    (message "Die Installation wurde abgebrochen. Sie sollten eventuelle Teilinstallationen löschen.")
)

(complete 0)

    ; just in case the installation was restarted

    ; see if this is really an update

(set is_update 0)
(set installdest (getassign "MaVi" "a"))

    ; if update, be sure they want program in same place

(if installdest
    (if (askbool
            (prompt "Sie haben schon ein MaVi-System im Verzeichnis\n\n\""
                    installdest
                    "\"\n\ninstalliert.\nSoll diese Version überschrieben werden (nicht empfohlen)?"
            )
            (help
                "Wie es scheint, hatten Sie MaVi schon einmal auf diesem Rechner installiert. "
                "Da dies die Previewversion 1A ist, sollten Sie mit der Installation nur fortfahren, "
                "falls Sie diese Version erneut installieren wollen. Andernfalls können Sie diese "
                "Previewversion in ein anderes Verzeichnis installieren oder aber die Installation jetzt "
                "abbrechen."
            )
            (default 1)
        )

        (set is_update 1)        ; if user wants in same place

        (set installdest        ; if user wants in different place
            (tackon
                (askdir
                    (prompt "In welchem Verzeichnis soll der MaVi Ordner angelegt werden?")
                    (help @askdir-help)
                    (default @default-dest)
                )
                "MaVi"
            )
        )
    )
; else
    (set installdest
        (tackon
            (askdir
                (prompt "In welchem Verzeichnis soll der MaVi Ordner angelegt werden?")
                (help @askdir-help)
                (default @default-dest)
            )
            "MaVi"
        )
    )
)

(if (not is_update)
    (
        (makedir installdest (infos))

        (tooltype
            (dest installdest)
            (noposition)
        )
    )
)
; from now on I'll work with this assign
(makeassign "MaVi" installdest)

; now lock on to disk 1, Demo only
(makeassign "installdisk1" "Disk1")



    ; at this point we have a valid destination, so we tell installer where
    ; the application will end up so the exit page will be correct -- also,
    ; the installation log file (if any) will be copied to the destination
(set @default-dest installdest)

(complete 20)

; these libraries are not only needed be mavi but may also be used by other programs
; or may already present on this system, so use copylib here

(copylib
    (source "installdisk1:libs/hrtool.library")
    (dest "LIBS:")
)

(copylib
    (source "installdisk1:libs/gaudio.library")
    (dest "LIBS:")
)

(copylib
    (source "installdisk1:libs/cyberext.library")
    (dest "LIBS:")
)

(copylib
    (source "installdisk1:libs/registry.library")
    (dest "LIBS:")
)

(copylib
    (source "installdisk1:libs/regprefs.library")
    (dest "LIBS:")
)

(copyfiles
    (source "installdisk1:devs/registry.new")
    (dest "devs:")
)

(copyfiles
    (source "installdisk1:devs/registry.old")
    (dest "devs:")
)

(makedir "MaVi:libs")
(makedir "MaVi:libs/MaVi")

(if (not is_update)
    (
        ; do not use copylib here
        (copyfiles
            (source "installdisk1:libs/mavikey.library")
            (dest "Mavi:Libs/Mavi/")
        )

        (copyfiles
            (source "installdisk1:libs/mavititle.data")
            (dest "Mavi:libs/Mavi/")
        )
    )
)

; unpack the archives to their destination, maybe later into a temp dir and then
; with copylib a version check

(run "installdisk1:cinst/lhX x installdisk1:font.lha fonts:")
(run "installdisk1:cinst/lhX x installdisk1:images.lha MaVi:")
(run "installdisk1:cinst/lhX x installdisk1:experimental.lha MaVi:")

; remove the assign, demo only
(makeassign "installdisk1")
(complete 40)

; now lock on to disk 2, Demo only
(makeassign "installdisk2" "Disk2")

(copyfiles
    (source "installdisk2:")
    (dest "Mavi:")
    (all)
)
(delete "mavi:disk.info" (safe))

; remove the assign, demo only
(makeassign "installdisk2")

(makedir "MaVi:Cache")

(complete 90)

    ; modify S:User-Startup

(startup "MaVi"
    (prompt
        "Einige Instruktionen müssen nun in die \"user-startup\" "
        "eingefügt werden.")
    (help "Ohne diese Instruktionen funktioniert MaVi nicht!")
    (command
        "ASSIGN MaVi: \"" installdest "\"\n"
        "ASSIGN Images: MaVi:Images add\n"
        "ASSIGN Libs: MaVi:Libs add\n"
        "ASSIGN ImageCache: MaVi:Cache add\n"
    )
)


(complete 100)

(message "MaVi wurde komplett installiert. Nach einem Neustart können Sie das System nutzen.")

    ; this is not strictly necessary, but doesn't hurt -- there is always
    ; a default (exit) at the end of any script
(exit)